Simple /warn script

[MrTibo]

For servers that need a simple warn script that keeps track of a player's history

(Doesn't include any automatic punishment system)

#██╗    ██╗ █████╗ ██████╗ ███╗   ██╗
#██║    ██║██╔══██╗██╔══██╗████╗  ██║
#██║ █╗ ██║███████║██████╔╝██╔██╗ ██║
#██║███╗██║██╔══██║██╔══██╗██║╚██╗██║
#╚███╔███╔╝██║  ██║██║  ██║██║ ╚████║
# ╚══╝╚══╝ ╚═╝  ╚═╝╚═╝  ╚═╝╚═╝  ╚═══╝
# Made by MrTibo

# Commands
# /warn <player> [reason]
# /warns [player]
# /delwarn <player> <warn nr.>
# /clearwarns <player>

# Configuration section
options:
	# Prefix
	prefix: &c&lWARN
	# Text color
	tc: &6
	# Highlight color
	hc: &e
	# Warn admin (/warn, /delwarn, /clearwarns)
	perm: warn.admin
	# View warns permission
	permvw: warn.viewwarns

# Script

command /warn [<offlineplayer>] [<text>]:
	permission: {@perm}
	permission message: &cNo permission
	usage: /warn <player> [reason]
	trigger:
		if arg 1 is set:
			if arg 2 is not set:
				add "(No reason given) &7- [%now%]" to {warns::%arg 1's uuid%::*}
				broadcast "{@prefix} {@hc}%arg 1% {@tc}was warned"
			if arg 2 is set:
				add "%colored arg 2% &7- [%now%]" to {warns::%arg 1's uuid%::*}
				broadcast "{@prefix} {@hc}%arg 1% {@tc}was warned for {@hc}%colored arg 2%"
		else:
			send "{@prefix} {@tc}Please provide a player"

command /delwarn <player> <int>:
	usage: /delwarn <player> <warn nr>
	permission: {@perm}
	trigger:
		if {warns::%arg 1's uuid%::%arg 2%} is set:
			delete {warns::%arg 1's uuid%::%arg 2%}
			send "{@prefix} {@tc}Warn deleted"
			loop {warns::%arg 1's uuid%::*}:
				add loop-value to {_warns::*}
			clear {warns::%arg 1's uuid%::*}
			loop {_warns::*}:
				add loop-value to {warns::%arg 1's uuid%::*}
		else:
			send "{@prefix} {@tc}This warn number wasn't found"

command /clearwarns <player>:
	permission: {@perm}
	trigger:
		delete {warns::%arg's uuid%::*}
		send "{@prefix} {@tc}Warns deleted"
		send "{@prefix} {@tc}Your warns were cleared" to arg

command /warns [<offlineplayer>]:
	permission: {@permvw}
	usage: /warns [player]
	trigger:
		if arg is set:
			send "{@prefix} {@hc}%arg% {@tc}has {@hc}%size of {warns::%arg's uuid%::*}% {@tc}warns"
			loop {warns::%arg's uuid%::*}:
				send "{@hc}%loop-index% &7- {@tc}%loop-value%"
		else:
			send "{@prefix} {@tc}Checking warns of all online players"
			loop all players:
				if size of {warns::%loop-player's uuid%::*} >= 1:
					send "{@prefix} {@hc}%loop-player% {@tc}has {@hc}%size of {warns::%loop-player's uuid%::*}% {@tc}warns"
					loop {warns::%loop-player's uuid%::*}:
						send "{@hc}%loop-index-1% &7- {@tc}%loop-value-2%"

 

[_Tarna_]

Cool Skript!