I need a Vanish Skript if it is possible (Skript Plugin)

[Multiplayersam]

Heya. I want a vansh Skript (If possible) Please, tell me what I must do in the Skript Files for it. Also, I am in need of a random items every _ Second skript with a /toggle feature

 

[mj80]

Random item:

options:
	prefix: &aRandom Items >
	item-every: 15 # one item every X amount of seconds
	toggle-command: /toggleitem # MUST HAVE A / AT THE BEGINNING
	on-message: &7Toggled &aon &7random items.
	off-message: &7Toggled &coff &7random items.


every {@item-every} seconds:
	loop all players:
		if {toggleitems.%loop-player%} is true:
			give loop-player 1 of random items out of all items

command {@toggle-command}:
	trigger:
		if {toggleitems.%player%} is true:
			set {toggleitems.%player%} to false
			send "{@prefix} {@off-message}"
		else:
			set {toggleitems.%player%} to true
			send "{@prefix} {@on-message}"

Vanish:

options:
	prefix: &cVANISH> 
	vanish-permission: sk.vanish
	join-message: &7%player% joined!
	leave-message: &7%player% left.

command /vanish:
	permission: {@vanish-permission}
	trigger:
		if {vanish.%player%} is true:
			set {vanish.%player%} to false
			broadcast "{@join-message}"
			reveal player to all players
			add 1 to {players.online}
			loop all players:
				if loop-player has permission "{@vanish-permission}":
					send "&a&lStaff &8▪ &a%player% &7unvanished." to loop-player
		else:
			set {vanish.%player%} to true
			broadcast "{@leave-message}"
			hide player from all players
			remove 1 from {players.online}
			loop all players:
				if loop-player has permission "sk.vanish":
					send "{@prefix} &a%player% &7vanished." to loop-player
					reveal player to loop-players

 

Edited July 8, 2020 by mj80

[Spiderlogical]

The only problem with the vanish skript is that if another player joins, or relogs they'll be able to see the person in vanish.

[MCXPStudios78]

This one is on the Plugin list, unless it is just me.

Edited July 8, 2020 by MCXPStudios78

[egirlism]

# Vanish.sk by egirlism

# Version: 1.3

 

options:

    logo: &7[&l&bVanish&r&7]

    permission: vanish.use

    permissionm: &cYou do not have access to this command!

    permissionalert: vanishalert.use

 

command /vanish [<offline player>]:

    permission: {@permission}

    permission message: {@permissionm}

    aliases: /v

    executable by: player

    trigger:

        if arg 1 is not set:

            if {vanish.%player%} is not set:

                hide the player from all players

                apply infinite invisibility without any particles to player

                apply infinite invulnerability to player

                send "{@logo} &fYou are now in &b&lVanish&f." to player

                send action bar message "&7&l&oVanish&r" to player

                set {vanish.%player%} to true

                set {Invisibility.%player%} to true

                loop all players:

                    if loop-player has permission "{@permissionalert}":

                        send "{@logo} &fThe player &e&o%player%&r &fis now in &b&lVanish&r&f." to loop-player

            else:

                reveal the player from all players

                remove invisibility from player

                remove invulnerability from player

                send "{@logo} &fYou are no longer in &b&lVanish&f." to player

                delete {vanish.%player%}

                delete {Invisibility.%player%}

                broadcast "&b&l&o%player%&r &fjoined the server" to all players

                loop all players:

                    if loop-player has permission "{@permissionalert}":

                        send "{@logo} &fThe player &e&o%player%&r &fis no longer in &b&lVanish&r&f." to loop-player

        else:

            if arg-1 is online:

                if {vanish.%arg-1%} is not set:

                    hide arg-1 from all players

                    apply infinite invisibility without any particles to arg-1

                    apply infinite invulnerability to arg-1

                    send "{@logo} &fYou are now in &b&lVanish&f." to arg-1

                    send action bar message "&7&l&oVanish&r" to arg-1

                    set {vanish.%arg-1%} to true

                    set {Invisibility.%arg-1%} to true

                    loop all players:

                        if loop-player has permission "{@permissionalert}":

                            send "{@logo} &fThe player &e&o%arg-1%&r &fis now in &b&lVanish&r&f." to loop-player

                else:

                    reveal arg-1 from all players

                    remove invisibility from arg-1

                    remove invulnerability from arg-1

                    send "{@logo} &fYou are no longer in &b&lVanish&f." to arg-1

                    delete {vanish.%arg-1%}

                    delete {Invisibility.%arg-1%}

                    broadcast "&b&l&o%arg-1%&r &fjoined the server" to all players

                    loop all players:

                        if loop-player has permission "{@permissionalert}":

                            send "{@logo} &fThe player &e&o%arg-1%&r &fis no longer in &b&lVanish&r&f." to loop-player

            else:

                send "{@logo} &cThe player &e%arg-1% &cis not online!" to player

 

on consume of milk:

    if {vanish.%player%} is true:

        if {Invisibility.%player%} is true:

            cancel event

            send "{@logo} &cYou cannot consume &7&lMilk&r &cwhile in &b&lVanish&r&c!" to player

 

on quit:

    if {vanish.%player%} is set:

        reveal the player from all players

        remove invisibility from player

        remove invulnerability from player

        delete {vanish.%player%}

        delete {Invisibility.%player%}

        cancel event

        send action bar message "" to player

 

on leave:

    if {vanish.%player%} is set:

        cancel event

 

[Pryzmm]

Please make sure that you aren't responding to posts that haven't been responded to in over a month. Thanks!