i need a money skript

[crainer1]

can someone make a skript for me that alows u to take away people money and give peoples money and pay people money???

i really need it for my friend

[CoolProgrammer]

On 3/24/2021 at 1:30 AM, crainer1 said:

can someone make a skript for me that alows u to take away people money and give peoples money and pay people money???

i really need it for my friend

 

Here's the 10 mins worth of efforts. Enjoy!

options:
    eco-usage-message: &cUsage: /eco (set/add/remove) (player) (amount).
    pay-usage-message: &cUsage: /eco (player) (amount).
    min-amount: 10

command /eco <text> <offline player> <number>:
    permission: op
    usage: {@eco-usage-message}
    trigger:
        if arg 1 is "set":
            setBal(arg-2, arg-3, sender)
            stop
        if arg 1 is "add":
            addBal(arg-2, arg-3, sender)
            stop
        if arg 1 is "remove":
            removeBal(arg-2, arg-3, sender)
            stop
        send "{@eco-usage-message}" to player

command /bal [<offline player>]:
    trigger:
        if arg 1 is set:
            send "&7Player &b%arg-1% &7has &a$%getBal(arg-1)%&7."
            stop
        send "&7You have &a$%getBal(player)%&7."

command /pay <offline player> <number>:
    usage: {@pay-usage-message}
    trigger:
        if exists(arg-1) is false:
            send "&cPlayer %arg-1% &cdoesn't exist."
            stop
        if getBal(player) < arg-2:
            send "&cNot enough money."
            stop
        if arg-2 < {@min-amount}:
            send "&cMinimum amount that you can pay is ${@min-amount}."
            stop
        addBal(arg-1, arg-2, null)
        removeBal(player, arg-2, null)
        send "&aYou paid $%arg-2%&a to %arg-1%&a." to player
        send "&aYou recieved $%arg-2%&a from %player%&a." to arg 1

function setBal(p: offline player, n: number, cb: sender):
    set {_u} to {_p}'s uuid
    set {balance::%{_u}%} to {_n}
    send "&aSet %{_p}%&a's balance to $%{_n}%&a." to {_cb}
    send "&aYour balance was set to $%{_n}%&a." to {_p}

function addBal(p: offline player, n: number, cb: sender):
    set {_u} to {_p}'s uuid
    add {_n} to {balance::%{_u}%}
    send "&aAdded $%{_n}% &ato %{_p}%&a's balance." to {_cb}
    send "&a$%{_n}%&a were added to your balance." to {_p}

function removeBal(p: offline player, n: number, cb: sender):
    set {_u} to {_p}'s uuid
    remove {_n} from {balance::%{_u}%}
    send "&aRemoved $%{_n}% &afrom %{_p}%&a's balance." to {_cb}
    send "&a$%{_n}%&a were removed your balance." to {_p}

function getBal(p: offline player) :: number:
    set {_u} to {_p}'s uuid
    return ({balance::%{_u}%} ? 0)

function exists(p: offline player) :: boolean:
    set {_u} to {_p}'s uuid
    return true if {balance::%{_u}%} is set
    return false

 

Edited March 29, 2021 by CoolProgrammer
Stupid bug.