Looking for Experienced Skripter. *(Paying for quality work)*

[ryzer]

A skript idea that I need in my server.

- Npcs (police) can spawn at a players island, at random times (every couple hours or so).
- Police will chase/follow/run to the player, to search them (stop the players actions, and freeze them for like 5 seconds to do the *search*)
- IF the player has certain items in their inventory when searched, they will be fined/jailed. 

(These items are usually just minecraft items with custom textures and renamed, so you would need to detect if the player is holding for example a Green-dye, with NBT 1 tag(s) and the name 'name_example'. 

I know most of that is pretty easy to do if you are good at skript, apart from detecting an item with nbt data or a name if that works.
If you think this is something you'd be able to tackle give me a shout and we can discuss price, if its too difficult sorry;) 

[condoogle]

dont pay someone to do this, this can easily be done with citizens, sentinels and a bit of semi advanced skript

[Pryzmm]

10 hours ago, condoogle said:

dont pay someone to do this, this can easily be done with citizens, sentinels and a bit of semi advanced skript

i mean... im not self advertizing or anything buuuut...

[Wyndexx]

@ryzerI think I could do this

I started on it because it looked like a neat challenge, and I have a question: do you want the player islands to be individual or have only one main island?

Don't pay though, if you insist the only thing I'll take in return is a rank on the server.

 

My best try:

Spoiler

# ########################
#          Police         
# ########################
#           V 1.0      
#  Developed by Gam3rBoi

# Police search you for 
# illegal items, and even
# will jail you if you
# carry some on you...
# They despawn after
# a little bit of time.

# DEPENDENCIES
#     Skript
#     SkRayFall (I think? on player move event might not be supported by basic skript)

# ILLEGAL ITEM FORMAT
# "&c&lILLEGAL ITEM"

# ######## Options ########
options:
	testitem: birch plank named "&aHEHEHE" with lore "&8GET CAUGHT, ROBBER" and "&c&lILLEGAL ITEM" # {@testitem}
	
	islandcoords: location(0, 65, 0, world("INSERT_ISLAND")) # {@islandcoords}
	
	jailcoords: location(100, 65, 100, world("INSERT_JAIL")) # {@jailcoords}
#CHANGE THE TWO ABOVE TO THE CORRECT COORDS, last argument is the world

# ######## Commands ########
# for a player executed search
command /search <player>:
	permission: pol.search.player
	trigger:
		set {pol::beingSearched::%arg-1%} to "TRUE"
		send "&9&lA police officer has started to search you. Be patient, and do not move." to arg-1
		wait 1 second
		loop all items in inventory of arg-1:
			if lore of loop-item contains "&c&lILLEGAL ITEM":
				set loop-item to air
				teleport arg-1 to {@jailcoords}
				send "&c&lOH NO! &fA police found you with an illegal item. You have been put in jail." to arg-1
				delete {pol::beingSearched::%arg-1%}
				stop
			else:
				wait 2 ticks #search delay: the more items you have, the greater the delay in the search
				continue
		delete {pol::beingSearched::%arg-1%}
		send "&aThe police search found nothing illegal on you. Good job!" to arg-1
				
command /getTestItem:
	permission: pol.test.item
	trigger:
		give player {@testitem}
		
command /testpolice:
	permission: pol.test.police
	trigger:
		spawn a zombie
		set {_z} to last spawned zombie
		set display name of {_z} to "&9&lPolice Officer"
		set {_pa} to unbreakable leather helmet
		dye {_pa} blue
		set helmet slot of {_z} to {_pa}
		set {_pa} to unbreakable leather chestplate
		dye {_pa} blue
		set chestplate slot of {_z} to {_pa}
		set {_pa} to unbreakable leather leggings
		dye {_pa} blue
		set leggings slot of {_z} to {_pa}
		set {_pa} to unbreakable leather boots
		dye {_pa} blue
		set boots slot of {_z} to {_pa}
		set tool of {_z} to stick named "&9Police Club"
		wait 10 minutes
		teleport {_z} to location(0, 256, 0, world("%{_z}'s world%"))
		kill {_z}

# ######## Timed Events ########
# you can change this if you want
every 150 minutes:
	spawn a zombie at {@islandcoords}
	set {_z} to last spawned zombie
	set display name of {_z} to "&9&lPolice Officer"
	set {_pa} to unbreakable leather helmet
	dye {_pa} blue
	set helmet slot of {_z} to {_pa}
	set {_pa} to unbreakable leather chestplate
	dye {_pa} blue
	set chestplate slot of {_z} to {_pa}
	set {_pa} to unbreakable leather leggings
	dye {_pa} blue
	set leggings slot of {_z} to {_pa}
	set {_pa} to unbreakable leather boots
	dye {_pa} blue
	set boots slot of {_z} to {_pa}
	set tool of {_z} to stick named "&9Police Club"
	wait 10 minutes
	teleport {_z} to location(0, 256, 0, world("%{_z}'s world%"))
	kill {_z}

# ######## Checks ########
on player move:
	if {pol::beingSearched::%player%} is set:
		cancel event
		send "&cYou are still being searched by a police officer." to player

on damage:
	if victim is zombie:
		if victim's name is "&9&lPolice Officer":
			if attacker is player:
				cancel event
				send "&c&lYou cannot hurt a police officer!" to attacker
	else if victim is a player:
		if attacker is a zombie:
			if attacker's name is "&9&lPolice Officer":
				cancel event
				if {pol::beingSearched::%victim%} is not set:
				
					set {pol::beingSearched::%victim%} to "TRUE"
					send "&9&lA police officer has started to search you. Be patient, and do not move." to victim
					wait 1 second
					loop all items in inventory of victim:
						if lore of loop-item contains "&c&lILLEGAL ITEM":
							set loop-item to air
							teleport victim to {@jailcoords}
							send "&c&lOH NO! &fA police found you with an illegal item. You have been put in jail." to victim
							delete {pol::beingSearched::%victim%}
							stop
						else:
							wait 2 ticks #search delay: the more items you have, the greater the delay in the search
							continue
					delete {pol::beingSearched::%victim%}
					send "&aThe police search found nothing illegal on you. The police officer left. Good Job!" to victim
					teleport attacker to location(0, 256, 0, world("%attacker's world%"))
					kill attacker
						
on death of zombie:
	if name of victim is "&9&lPolice Officer":
		clear the drops
		
on skript load:
	send "[POLICE] Skript loaded successfully." to console

 

 

Edited January 5, 2022 by Gam3rBoi
Added skript