Simple Dash Script

[xlr100]

Here is a simple dash script i made out of boredom, and because normal PvP sucks

Note: You dash when you rightclick with a sword or leftclick with a bow

Additional Note: You can change the cooldown between dashes and the speed of the dashes in the options section

options:
    Cooldown: 3 seconds
    Speed: 2
    
on rightclick with a sword:
    Dash(player)

on leftclick with a bow:
    Dash(player)
        
function Dash(p: player):
    set {_u} to {_p}'s uuid
    if {dash.last::%{_u}%} is set:
        set {_wait} to difference between {dash.last::%{_u}%} and now
    else:
        set {_wait} to {@Cooldown}
    if {_wait} >= {@Cooldown}:
        set {dash.last::%{_u}%} to now
        if {_p} is on ground:
            push {_p} forwards at speed {@Speed}
        else:
            push {_p} forwards at speed {@Speed} / 2
    else:
        send action bar "&cCD: %difference between {_wait} and {@Cooldown}% left" to {_p}

Edited January 14, 2020 by OMan100