How do you make players talk in chat with a skript?

[MQXO]

I am pretty new to skripting and i know kinda what im doing with commands but I've never been able to figure this one out;

The commands I'm trying to get are; /forcechat [player] [message] and /forcechatall [message]

I feel as though the parameters are pretty self explanitory but in case you dont get it, /forcechatall would force everyone to say the message inputted in the "[messsage]" field, and /forcechat would make the player entered in the "[player]" field say the message in the "[message]" field.

[KJPAKA]

This is a fully functioning Skript i made for you.

command /forcechat [<offline player>] [<text>]:
    permission: op
    permission message: &CNo permission!
    usage: &c/forcechat <player> <message>
    trigger:
        if arg-1 is set:
            if arg-2 is set:
                set {_p} to arg-1
                if {_p} is online:
                    make {_p} send message arg-2
                else:   
                    send "&cYou can't sudo a offline player" to player
            else:
                send "&CPlease specify a message!" to player
        else:
            send "&cPlease specify a player!" to player

command /forcechatall [<text>]:
    permission: op
    permission message: &CNo permission!
    usage: &c/forcechatall
    trigger:
        if arg-1 is set:
            loop all players:
                make loop-player send message arg-1
        else:
            send "&cPlease specify a message!" to player

 

[MQXO]

1 hour ago, KJPAKA said:

This is a fully functioning Skript i made for you.

command /forcechat [<offline player>] [<text>]:
    permission: op
    permission message: &CNo permission!
    usage: &c/forcechat <player> <message>
    trigger:
        if arg-1 is set:
            if arg-2 is set:
                set {_p} to arg-1
                if {_p} is online:
                    make {_p} send message arg-2
                else:   
                    send "&cYou can't sudo a offline player" to player
            else:
                send "&CPlease specify a message!" to player
        else:
            send "&cPlease specify a player!" to player

command /forcechatall [<text>]:
    permission: op
    permission message: &CNo permission!
    usage: &c/forcechatall
    trigger:
        if arg-1 is set:
            loop all players:
                make loop-player send message arg-1
        else:
            send "&cPlease specify a message!" to player

 

Thanks, I'm 100% gonna study this so i can figure out what the hell I'm doing.

[KJPAKA]

Alright, if you have any questions feel free to contact me.

[mattwithabat]

https://en.njol.ch/projects/skript/doc
this can help

[OMGPandaYT2]

they made that way to hard this is very simple:

command /chat <player> <text>:

    permission: chat

    trigger:

        make arg-1 say arg-2                                                                                                                                    

[KJPAKA]

What i did was i made it so it checked if it was set and other stuff to make it fancy. Also, use [<offline player>] and [<text>] instead. But yes that would work as well. I also made it check if the player was online etc.

Edited May 31, 2020 by KJPAKA

[UntitledGoose]

2 hours ago, KJPAKA said:

What i did was i made it so it checked if it was set and other stuff to make it fancy. Also, use [<offline player>] and [<text>] instead. But yes that would work as well. I also made it check if the player was online etc.

you could've just not used optional arguments, have put `usage: &c/forcechat (player) (message)` before the trigger and made it use a player argument instead of an offlineplayer argument

[KJPAKA]

I use offline player because then you can tab the name.

[Nateee]

Changing the alias would be cooler, like mail, or message. So like, /m. But this is a great skript super simply and works perfectly.